<% Option Explicit %>
<!--#include file="common.asp" -->
<!--#include file="functions/functions_common.asp" -->
<!--#include file="functions/functions_hash1way.asp" -->
<!--#include file="functions/functions_send_mail.asp" -->
<%
'****************************************************************************************
'**  Copyright Notice    
'**
'**  Web Wiz Guide - Web Wiz Mailing List
'**                                                              
'**  Copyright 2001-2004 Bruce Corkhill All Rights Reserved.                                
'**
'**  This program is free software; you can modify (at your own risk) any part of it 
'**  under the terms of the License that accompanies this software and use it both 
'**  privately and commercially.
'**
'**  All copyright notices must remain in tacked in the scripts and the 
'**  outputted HTML.
'**
'**  You may use parts of this program in your own private work, but you may NOT
'**  redistribute, repackage, or sell the whole or any part of this program even 
'**  if it is modified or reverse engineered in whole or in part without express 
'**  permission from the author.
'**
'**  You may not pass the whole or any part of this application off as your own work.
'**   
'**  All links to Web Wiz Guide and powered by logo's must remain unchanged and in place
'**  and must remain visible when the pages are viewed unless permission is first granted
'**  by the copyright holder.
'**
'**  This program is distributed in the hope that it will be useful,
'**  but WITHOUT ANY WARRANTY; without even the implied warranty of
'**  MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE OR ANY OTHER 
'**  WARRANTIES WHETHER EXPRESSED OR IMPLIED.
'**
'**  You should have received a copy of the License along with this program; 
'**  if not, write to:- Web Wiz Guide, PO Box 4982, Bournemouth, BH8 8XP, United Kingdom.
'**    
'**
'**  No official support is available for this program but you may post support questions at: -
'**  http://www.webwizguide.info/forum
'**
'**  Support questions are NOT answered by e-mail ever!
'**
'**  For correspondence or non support questions contact: -
'**  info@webwizguide.info
'**
'**  or at: -
'**
'**  Web Wiz Guide, PO Box 4982, Bournemouth, BH8 8XP, United Kingdom
'**
'****************************************************************************************


'Set the response buffer to true as we maybe redirecting
Response.Buffer = True 

'Declare variables
Dim rsCategories	'Recordset to hold the categories
Dim strEmail		'Holds the users e-mail address
Dim strOldEmail		'Hols teh users old email address
Dim strUserName		'Holds the members name
Dim strPassword		'Holds the user password
Dim strUsersSalt	'Holds the salt value for ecrypted passwords
Dim strOldPassword	'Holds the old password for the user
Dim strOldSalt		'Holds the salt value for the old password
Dim strOldPasswordInput	'Holds the old password the user has entered
Dim blnHTMLformat	'Set to true if email is to be in HTML format
Dim blnEmailOK		'Set to true if the email address is valid
Dim lngMemberID		'Holds the members ID number
Dim laryCatID		'Holds the cat ID
Dim blnChecked		'Set to true if the category checkbox is to be checked
Dim blnConfirmPassOK	'Set to true if the old password matches the confirmed pass
Dim blnUpadteEmailAddr	'Set to true if updating the users email address
Dim blnUpdatePass	'Set to true if the password is updated
Dim strSubject		'Holds the subject of te email
Dim strEmailBody	'Holds the email body
Dim strUserID 		'Holds the users ID


'Initialise variables
blnEmailOK = True
blnConfirmPassOK = True
lngMemberID = 0
blnUpdatePass = false


'Read in the users ID code
strUserID = Trim(Mid(Request.QueryString("ID"), 1, 22)) 

'Clean up the USER ID address getting rid of unwanted characters
strUserID = IDcharacterStrip(strUserID)


'Get the users details from the database
If NOT strUserID = "" Then
	
	'Initalise the strSQL variable with an SQL statement to query the database
	strSQL = "SELECT " & strDbTable & "Members.* " & _
	"FROM " & strDbTable & "Members " & _
	"WHERE " & strDbTable & "Members.ID_Code = '" & strUserID & "';"
	
	With rsCommon
			
		'Set the cursor type property of the record set to Dynamic so we can navigate through the record set
		.CursorType = 2
				
		'Set the Lock Type for the records so that the record set is only locked when it is updated
		.LockType = 3
				
		'Query the database
		.Open strSQL, adoCon
		
		'If a record is found read in the details
		If NOT .EOF Then
			
			'Get the email address
			lngMemberID = .Fields("Mail_ID")
			strUserName = .Fields("Name")
			strOldEmail = .Fields("Email")
			strOldPassword = .Fields("Password")
			strOldSalt = .Fields("Salt")
			blnHTMLformat = CBool(.Fields("HTMLformat"))
		End If
	
		
	End With

'If the user code is not enterd or does not match bounce the user to the login page
Else

	'Clean up
	Set rsCommon = Nothing
	adoCon.Close
	Set adoCon = Nothing    
						
	'Redirect to login page
	Response.Redirect("default.asp")
end if


'Read in the form details
If Request.Form("postBack") Then
	
	'Read in the email address
	strEmail = Trim(Mid(LCase(Request("email")), 1, 35))
	
	'Clean up the email address address getting rid of unwanted characters
	strEmail = characterStrip(strEmail)
	
	'Check to see if the user has entered an e-mail address and that it is a valid address
	If Len(strEmail) < 5 OR NOT Instr(1, strEmail, " ") = 0 OR InStr(1, strEmail, "@", 1) < 2 OR InStrRev(strEmail, ".") < InStr(1, strEmail, "@", 1) Then
		
		'Set an error message if the users has not enetered a valid e-mail address
		blnEmailOK = False 
		
	'Else the email address is OK
	Else
		blnEmailOK = True
	End If	
	
	'Read in the form details
	strUserName = removeAllTags(Trim(Mid(Request.Form("name"), 1, 25)))
	strPassword = removeAllTags(Trim(Mid(Request.Form("password"), 1, 25)))
	strOldPasswordInput = removeAllTags(Trim(Mid(Request.Form("oldPassword"), 1, 25)))
	If blnPlainTextOption = true Then blnHTMLformat = CBool(Request.Form("HTMLformat")) Else blnHTMLformat = true
End If


'If this is a post back run update code
If Request.Form("postBack") AND blnEmailOK AND strUserName <> "" Then
	
		
	'Check the password if the user is updating their password
	If strPassword <> "" Then
	
		'If the passwords are encrypted first encrypt the password
		If blnEncryptPasswords Then strOldPasswordInput = HashEncode(strOldPasswordInput & strOldSalt)
			
		'Check the old password is correct
		If strOldPasswordInput = strOldPassword Then 
		
			'If the password is to be encrypted then do so
			If blnEncryptPasswords Then
				
				'Create a new salt value
				strUsersSalt = hexValue(Len(strPassword))
				
				'Encrypt the password
				strPassword = HashEncode(strPassword & strUsersSalt)
				
				'Update the recordset
				rsCommon.Fields("Salt") = strUsersSalt
			End If
		
			'Update recordset with new password
			rsCommon.Fields("Password") = strPassword
			
			'Set the conformed pass is OK
			blnConfirmPassOK = True
			blnUpdatePass = True
		
		'Else the conirmed pass doesn't match the old one
		Else
		
		 	blnConfirmPassOK = false
		End If
	End If	
	
		
	'Check to see if the email address is being updated
	'If the email address are the same the email is not being updated
	If strOldEmail = strEmail Then 
		blnUpadteEmailAddr = false
	'The email address is being updated
	Else 
		blnUpadteEmailAddr = true 
		strOldEmail = strEmail 
	End If
	
	
	'Update the database
	If blnConfirmPassOK Then
		
		'Set database fields	
		rsCommon.Fields("Name") = strUserName
		If blnUpadteEmailAddr Then rsCommon.Fields("Email") = strEmail
		If blnActivate AND blnUpadteEmailAddr Then rsCommon.Fields("Active") = False
		rsCommon.Fields("HTMLformat") = blnHTMLformat	
			
		'Update the database
		rsCommon.Update
		
		
		'Delete category details from the database before the update
		strSQL = "DELETE FROM " & strDbTable & "MemCat WHERE " & strDbTable & "MemCat.Mail_ID=" & lngMemberID & ";"
		
		'Write to database 
		adoCon.Execute(strSQL) 
		
		'Add the category details to the database
		For each laryCatID in Request.Form("catID")
			
			'Add cat choices
			strSQL = "INSERT INTO " & strDbTable & "MemCat " & _
			"("  & _
			"[Mail_ID], " & _
			"[Cat_ID] " & _
			") " & _
			"VALUES " & _
			"('" & lngMemberID & "', " & _
			"'" & CLng(laryCatID) & "' " & _
			")" 
			
			'Write to database 
			adoCon.Execute(strSQL) 
		Next
		
		
		'If email activation is enabled then the user will need to re-activate their account so send email
		If blnActivate AND blnUpadteEmailAddr Then
			
			'Set the subject of the email
			strSubject = strWebsiteName & ": Re-Confirm Your Subscription To Mailing List"
				
			'set the message body of the activation email
			strEmailBody = "Hi " & strUserName & "," & _
			vbCrLf & vbCrLf & "Greetings from " & strWebsiteName & "." & _
			vbCrLf & vbCrLf & "You have sucessfully changed your " & strWebsiteName & " mailing list preferences." & _
			vbCrLf & vbCrLf & "As your email address has been changed you will need to re-activate your subscription by clicking the address below:-" & _
			vbCrLf & vbCrLf & strWebsiteAddress & "/activate.asp?M=RE&ID=" & strUserID & _
			vbCrLf & vbCrLf & "If you did not subscribe or this email is in error, then please just ignore it, you need do nothing more." & _
			vbCrLf & vbCrLf & "Thank-you for your interest." & _
			vbCrLf & vbCrLf & "Best Regards," & _
			vbCrLf & vbCrLf & strWebsiteName
				
			'Create email object
			Call createMailObject(strMailComponent)
				
			'***** START WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******	
			'Write a remove from mailing list message to add to the end of the e-mail in HTML Format
			strEmailBody = strEmailBody & mailBody("text", strEmail, blnLCode)  '- This needs to stay in place for the software to stay legal in most countries
			'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
					
			'Send the email
			Call SendMail(strUserName, strEmail, strMailComponent, "text")
			
			'Drop email component
			Call dropMailObject(strMailComponent)
			
			'Clean up
			rsCommon.close
			Set rsCommon = Nothing
			adoCon.Close
			Set adoCon = Nothing    
			
			
			'Redirect to actiavtion page
			Response.Redirect("management_centre_update.asp?ID=" & Server.URLEncode(strUserID) & "&PU=" & blnUpdatePass & "&RA=1")
		
		
		'Else send a mail letting the user know they have updated their prefences
		Else
		
			'Set the subject of the email
			strSubject = strWebsiteName & ": Mailing List Preferences Updated"
				
			'set the message body of the prefernce update email
			strEmailBody = "Hi " & strUserName & "," & _
			vbCrLf & vbCrLf & "Greetings from " & strWebsiteName & "." & _
			vbCrLf & vbCrLf & "You have sucessfully changed your " & strWebsiteName & " mailing list preferences." & _
			vbCrLf & vbCrLf & "If you would like to change your preferences again, you may do so through the Mailing List Management Centre at the following address:-" & _
			vbCrLf & strWebsiteAddress & "/default.asp?email=" & Server.URLEncode(strEmail) & _
			vbCrLf & vbCrLf & "Thank-you for your interest." & _
			vbCrLf & vbCrLf & "Best Regards," & _
			vbCrLf & vbCrLf & strWebsiteName
				
			'Create email object
			Call createMailObject(strMailComponent)
				
			'***** START WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******	
			'Write a remove from mailing list message to add to the end of the e-mail in HTML Format
			strEmailBody = strEmailBody & mailBody("text", strEmail, blnLCode)
			'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
					
			'Send the email
			Call SendMail(strUserName, strEmail, strMailComponent, "text")
			
			'Drop email component
			Call dropMailObject(strMailComponent)
			
			'Clean up
			rsCommon.close
			Set rsCommon = Nothing
			adoCon.Close
			Set adoCon = Nothing    
			
			
			'Redirect to actiavtion page
			Response.Redirect("management_centre_update.asp?ID=" & Server.URLEncode(strUserID) & "&PU=" & blnUpdatePass & "&RA=0")
		
			
		End If
	End If
End If

'Clean up
rsCommon.close

%>
<html>
<head>
<title>Mailing List: Management Centre</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<!-- Web Wiz Guide - Web Wiz Mailing List ver.<% = strVersion %> is written and produced by Bruce Corkhill Š2001-2004
     	 If you want your own FREE Mailing List then goto http://www.webwizmailinglist.com -->

<script language="JavaScript">

//Function to check form is filled in correctly before submitting
function CheckForm () {

	var errorMsg = "";

	//Check for a name
        if (document.frmManCen.name.value.length == ''){
                errorMsg += "\n\tName \t\t- Enter your name";
        }
        
        //If an e-mail is entered check that the e-mail address is valid
        if (document.frmManCen.email.value == "" || (document.frmManCen.email.value.indexOf("@",0) == -1||document.frmManCen.email.value.indexOf(".",0) == -1)) {
                errorMsg +="\n\tEmail\t\t- Enter your valid email address";

        }
        
         //Check for old password
        if ((document.frmManCen.password.value.length > 0) && (document.frmManCen.oldPassword.value == '')){
                errorMsg += "\n\tCurrent Password \t- Enter your Current Password";
        }

        //Check for a password
        if ((document.frmManCen.password.value.length <= 3) && (document.frmManCen.password.value.length > 0)){
                errorMsg += "\n\tNew Password \t- Your New Password must be at least 4 characters";
	}

        //Check both passwords are the same
        if ((document.frmManCen.password.value) != (document.frmManCen.password2.value)){
                errorMsg += "\n\tPassword Error\t- The passwords entered do not match";
                document.frmManCen.password.value = ""
                document.frmManCen.password2.value = ""
        }

	//If there is aproblem with the form then display an error
	if (errorMsg != ""){
		msg = "_______________________________________________________________\n\n";
		msg += "The form has not been submitted because there are problem(s) with the form.\n";
		msg += "Please correct the problem(s) and re-submit the form.\n";
		msg += "_______________________________________________________________\n\n";
		msg += "The following field(s) need to be corrected: -\n";

		errorMsg += alert(msg + errorMsg + "\n\n");
		return false;
	}

	return true;
}

</script>

<!-- #include file="includes/header.asp" -->
<div align="center">
  <span class="heading"><% = strWebsiteName %>'s Mailing List Management Centre</span><br /><%

'If there is a problem tell the user
If blnEmailOK = false OR (Request.Form("postBack") AND (strUserName = "")) Then

%>
   <table width="100%" border="0" cellspacing="0" cellpadding="0" align="center">
    <tr>
     <td align="center" class="error"><br />
      <strong>Your subscription update request could not be processed.</strong><br /><%
      
	If blnEmailOK = false Then
		Response.Write("The email address you entered is not valid! Please enter a valid email address.")
	ElseIf strUserName = "" Then
		Response.Write("Please enter a valid name.")
	ElseIf blnConfirmPassOK = false Then
		Response.Write("The password entered as the present password was incorrect.")
	End If
%>
    </tr>
   </table><%

End If

%>
  <br />
  <form name="frmManCen" method="post" action="management_centre.asp?ID=<% = Server.URLEncode(strUserID) %>" onSubmit="return CheckForm();">
   <table width="95%" border="0" cellspacing="0" cellpadding="1" bgcolor="<% = strTableBorderColour %>" align="center">
    <tr>
     <td>
      <table width="100%" border="0" cellpadding="0" cellspacing="0" bgcolor="<% = strTableBgColour %>">
       <tr>
        <td bgcolor="<% = strTableTitleColour %>">
         <table width="100%" border="0" cellspacing="1" cellpadding="3" bgcolor="<% = strTableBgColour %>">
          <tr bgcolor="<% = strTableTitleColour %>">
            <td colspan="2" background="<% = strTableTitleBgImage %>" class="tHeading">Your Account Details<span class="smText"> (all fields are required) </span></td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text"> If you would like to change your <% = strWebsiteName %>'s Mailing List details please use the form below. </td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td width="289" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">Name:</td>
           <td width="677" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text"><input name="name" type="text" id="name" size="25" maxlength="25" value="<% = strUserName %>" /></td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">Email Address:</td>
           <td bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>" class="text"><input name="email" type="text" id="email" size="25" maxlength="50" value="<% = strOldEmail %>" /></td>
          </tr><%

'If the user can choose to have a plain text email sent give them the option
If blnPlainTextOption Then
	
%>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">Email Delivery Format: </td>
           <td bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>" class="text"><input name="HTMLformat" type="radio" value="true"<% If blnHTMLformat Then Response.Write(" checked") %> />HTML&nbsp; <input name="HTMLformat" type="radio" value="false"<% If blnHTMLformat = false Then Response.Write(" checked") %> />Text </td>
          </tr><%
End If

%>
          <tr align="center" bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableBottomRowColour %>" class="text">&nbsp;</td>
          </tr>
        </table></td>
       </tr>
     </table></td>
    </tr>
   </table>
   <br>
   <table width="95%" border="0" cellspacing="0" cellpadding="1" bgcolor="<% = strTableBorderColour %>" align="center">
    <tr>
     <td>
      <table width="100%" border="0" cellpadding="0" cellspacing="0" bgcolor="<% = strTableBgColour %>">
       <tr>
        <td bgcolor="<% = strTableTitleColour %>">
         <table width="100%" border="0" cellspacing="1" cellpadding="3" bgcolor="<% = strTableBgColour %>">
          <tr bgcolor="<% = strTableTitleColour %>">
           <td colspan="2" background="<% = strTableTitleBgImage %>" class="tHeading">Your Password <span class="smText"></span></td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text"> If you would like to change your password fill in the form below. </td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td width="289" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">Current Password :</td>
           <td width="677" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text"><input name="oldPassword" type="password" id="oldPassword" size="25" maxlength="25" />
           &nbsp;&nbsp;<a href="forgot_password.asp?email=<% = Server.URLEncode(strEmail) %>" target="_self">Forgot your password?</a> </td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">New Password: </td>
           <td bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>" class="text"><input name="password" type="password" id="password" size="25" maxlength="25" /></td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">Confirm Password: </td>
           <td bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>" class="text"><input name="password2" type="password" id="password2" size="25" maxlength="25" /></td>
          </tr>
          <tr align="center" bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableBottomRowColour %>" class="text">&nbsp;             </td>
          </tr>
        </table></td>
       </tr>
     </table></td>
    </tr>
   </table>
   <br>
   <table width="95%" border="0" cellspacing="0" cellpadding="1" bgcolor="<% = strTableBorderColour %>" align="center">
    <tr>
     <td>
      <table width="100%" border="0" cellpadding="0" cellspacing="0" bgcolor="<% = strTableBgColour %>">
       <tr>
        <td bgcolor="<% = strTableTitleColour %>">
         <table width="100%" border="0" cellspacing="1" cellpadding="3" bgcolor="<% = strTableBgColour %>">
          <tr bgcolor="<% = strTableTitleColour %>">
           <td colspan="2" background="<% = strTableTitleBgImage %>" class="tHeading">Mailing List Categories </td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">You have subscribed to the checked <% = strWebsiteName %> mailing list categories below. To subscribe to additional categories, select the box next to the category title. To unsubscribe deselect the box. </td>
          </tr><%
          
'Initalise the strSQL variable with an SQL statement to query the database
strSQL = "SELECT " & strDbTable & "Category.* FROM " & strDbTable & "Category ORDER BY Cat_Order ASC;"
	
'Query the database
rsCommon.Open strSQL, adoCon
			
'Intialise the ADO recordset object
Set rsCategories = Server.CreateObject("ADODB.Recordset")

'Initalise the strSQL variable with an SQL statement to query the database
strSQL = "SELECT " & strDbTable & "MemCat.* FROM " & strDbTable & "MemCat WHERE " & strDbTable & "MemCat.Mail_ID=" & lngMemberID & ";"
	
'Query the database
rsCategories.Open strSQL, adoCon

	
'Loop through cats
Do While NOT rsCommon.EOF
	
	'Initliase variable
	blnChecked = false
	
	
	'Check to see if the user has checked this in last submission
	If Request.Form("postBack") Then
		For each laryCatID in Request.Form("catID")
			
			'If the cat has been checked before set blnChecked to true
			If CLng(laryCatID) = CLng(rsCommon("Cat_ID")) Then blnChecked = true
		Next
	
	'Else get the users choosen categories form the database
	ElseIf NOT rsCategories.EOF Then
		
		'Loop through records to see if the user has checked this cat
		Do While NOT rsCategories.EOF
		
			'If this cat is selected by the user then set checked boolen to true
			If CLng(rsCategories("Cat_ID")) = CLng(rsCommon("Cat_ID")) Then blnChecked = true
		
			'Move to next record
			rsCategories.MoveNext
		Loop	
		
		'Move to first record
		rsCategories.MoveFirst
		
	End If
	
	Response.Write(vbCrLf & "   <tr> " & _
	vbCrLf & "    <td width=""1%"" background=""" & strTableBgImage & """ bgcolor=""" & strTableColour & """ align=""right""><input type=""checkbox"" name=""catID"" id=""catID"" value=""" & rsCommon("Cat_ID") & """")
	If blnChecked = true then Response.Write(" checked")
	Response.Write(" /></td>" & _
	vbCrLf & "    <td width=""99%"" background=""" & strTableBgImage & """ bgcolor=""" & strTableColour & """ class=""text"">" & rsCommon("Cat_Name") & "</td>" & _
	vbCrLf & "   </tr>")
   
	'Move to next record in rs
	rsCommon.MoveNext
Loop

'Clean up
rsCategories.Close
Set rsCategories = Nothing
rsCommon.Close
Set rsCommon = Nothing
adoCon.Close
Set adoCon = Nothing    
 %>
          <tr align="center" bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableBottomRowColour %>" class="text">&nbsp;<input name="UID" type="hidden" id="UID" value="<% = strUserID %>" /><input type="hidden" name="postBack" value="true" /> </td>
          </tr>
        </table></td>
       </tr>
     </table></td>
    </tr>
   </table>
   <span class="text">
   <br>
   <input type="submit" name="Submit" value="Update My Account">
   </span>
  </form>
  <br /><br />
  <form action="delete_account.asp" method="post" name="frmDelete" target="_self" id="frmDelete" onSubmit="return confirm('Are you sure you wish to unsubscribe from <% = strWebsiteName %>\'s mailing list?');">
   <table width="95%" border="0" cellspacing="0" cellpadding="1" bgcolor="<% = strTableBorderColour %>" align="center">
    <tr>
     <td>
      <table width="100%" border="0" cellpadding="0" cellspacing="0" bgcolor="<% = strTableBgColour %>">
       <tr>
        <td bgcolor="<% = strTableTitleColour %>">
         <table width="100%" border="0" cellspacing="1" cellpadding="3" bgcolor="<% = strTableBgColour %>">
          <tr bgcolor="<% = strTableTitleColour %>">
           <td colspan="2" background="<% = strTableTitleBgImage %>" class="tHeading">Uunsuscribe form  Mailing List</td>
          </tr>
          <tr bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableColour %>" class="text">If you would like to unsubscribe from the <% = strWebsiteName %> mailing list and have your account permanently deleted, then click on the button below. <br>
            <br>
           Once you unsubscribe you will receive one last email from <% = strWebsiteName %> to confirm  that your subscription to the <% = strWebsiteName %> mailing list is closed.</td>
          </tr>
          <tr align="center" bgcolor="<% = strTableColour %>" background="<% = strTableBgImage %>">
           <td colspan="2" background="<% = strTableBgImage %>" bgcolor="<% = strTableBottomRowColour %>" class="text"><input name="UID" type="hidden" id="UID" value="<% = strUserID %>" />
           <input type="submit" name="Submit" value="Delete My Account">
           </td>
          </tr>
        </table></td>
       </tr>
     </table></td>
    </tr>
   </table>
  </form><%


Response.Write("<br />")


'***** START WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
If blnLCode = True Then
	Response.Write("<span class=""smText"">Powered by <a href=""http://www.webwizmailinglist.com"" target=""_blank"" class=""smLink"">Web Wiz Mailing List</a> version " & strVersion & "</span>")
	Response.Write("<br /><span class=""smText"">Copyright &copy;2001-2004 <a href=""http://www.webwizguide.info"" target=""_blank"" class=""smLink"">Web Wiz Guide</a></span>")
End If 
'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
 %>
  </div>
<!--#include file="includes/footer.asp" -->